PowerApps: Aprende a filtrar galerías por rangos de fechas

El día de hoy vamos a ver ejemplos de escenarios comunes para filtrar una galería de Powerapps por rangos de fechas. Por cada ejemplo veremos tanto código como su respectivo resultado de salida, solo tendremos que cambiar el nombre de la fuente de datos y los nombres de columna para que coincidan con los que estemos usando.

Para todos estos casos vamos a usar una lista de SharePoint llamada Calendar Dates que contiene días consecutivos.

1. Filtrar entre un rango de fechas definido por controles
2. Filtros por una fecha específica
3. Filtrar fechas en una semana o semanas específicas
4. Filtros para meses completos
5. Filtrar por trimestres
6. Filtrar todas las fechas de un año.

Controles de formulario

1. FILTRO DE GALERÍA CON DOS SELECTORES DE FECHA (INICIO Y FIN)

Antes que nada vamos a filtrar una galería para que solo muestre las fechas entre la fecha de inicio seleccionada y la fecha final en dos selectores de fecha.

Usando nuestra lista de SharePoint con días consecutivos haremos que nuestros selectores de fecha abarquen las fechas empezando el 01/01/2018 y terminando el 31/12/2024, lo cual nos dará 2557 filas.

Ahora vamos a crear dos selectores de fecha en una app de lienzo llamada dte_StartDate y dte_EndDate.

Y el código a usar será el siguiente:

Filter(
    'Calendar Dates',
    CalendarDate >= dte_StartDate.SelectedDate,
    CalendarDate <= dte_EndDate.SelectedDate
)

Como resultado de salida, la galería nos mostrará solo las filas de las fechas seleccionadas entre la fecha de inicio y la fecha final en los dos selectores de fecha. La fecha actual es 08/04/2021.

Por una fecha específica

2. FILTRO DE GALERÍA POR LA FECHA DEL DÍA DE HOY

En este caso vamos a filtrar la galería de Power Apps para que solo muestre las fechas que son iguales al día de hoy.

En base a nuestra lista de SharePoint, vamos a introducir el siguiente código en la propiedad Items de la galería:

With(
    {
        StartDate: Today(),
        EndDate: Today() + 1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate < EndDate
    )
)

Y como salida la galería solo nos mostrará una sola fila:

3. FILTRO DE GALERÍA POR LA FECHA DEL DÍA DE MAÑANA

Ahora vamos a filtrar la galería de Power Apps para que nos muestre solo las fechas que son iguales a la fecha del día de mañana.

Siguiendo con nuestra misma lista de SharePoint como entrada, el código a usar será el siguiente:

With(
    {
        StartDate: Today(),
        EndDate: Today() + 1
    },
    Filter(
        'Calendar Dates',
        CalendarDate > StartDate,
        CalendarDate <= EndDate
    )
)

Como valor de salida tendremos que la galería solo mostrará las filas con una fecha igual a la fecha de mañana, y siendo que la fecha del día de hoy es 08/04/2021, nos dará esto:

4. FILTRO DE GALERÍA POR FECHAS EN LOS SIGUIENTES ‘N’ DÍAS

Ahora vamos a filtrar la galería para que muestre solo las fechas dentro del siguiente número ‘N’ de días en donde ‘N’ es un número especificado por el creador de la app.[

Vamos a introducir este código en la propiedad Items de la galería:

With(
    {
        StartDate: Today(),
        EndDate: Today() + 5  // change this number
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Y en nuestra salida la galería solo mostrará las filas con una fecha en los siguientes cinco días. Siendo que la fecha actual es 08/04/2021 entonces obtendremos lo siguiente:

5. FILTRO DE GALERÍA POR LA FECHA DEL DÍA ANTERIOR

Ahora vamos a filtrar la galería para que muestre solo las fechas que son iguales a la fecha del día de ayer. Nuestro código a emplear es el siguiente:

With(
    {
        StartDate: Today()-1,
        EndDate: Today()
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate < EndDate
    )
)

Y como salida la galería solo nos mostrará las filas que tengan una fecha igual a la del día de ayer. Siendo la fecha actual 08/04/2021 entonces obtendremos lo siguiente:

6. FILTRO DE GALERÍA POR LAS FECHAS EN LOS ‘N’ DÍAS ANTERIORES

Con este filtro solo se nos mostrarán las fechas dentro del anterior ‘N’ número de días en donde ‘N’ es un número especificado por el creador de la app.

El código que usaremos en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Today() - 5, // change this value
        EndDate: Today()
    },
    Filter(
        'Calendar Dates',
        CalendarDate > StartDate,
        CalendarDate <= EndDate
    )
)

Como salida, la galería nos mostrará solo las filas con una fecha en los cinco días anteriores. Siendo nuestra fecha actual 08/04/2021 tendremos esto:

Por una semana completa

7. FILTRO DE GALERÍA POR FECHAS EN LA SEMANA ACTUAL

Ahora veremos filtros por semanas, empezando porque solo nos muestre las fechas en la semana actual.

Usaremos este código en la propiedad Items de la galería:

With(
    {
        StartDate: Today()-(Weekday(Today(), StartOfWeek.Monday))+1,
        EndDate: DateAdd(Today(),(7- Weekday(Today(),StartOfWeek.Sunday)),Days)
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como salida la galería nos mostrará solo las filas con una fecha en la semana actual, siendo nuestra fecha actual 08/04/2021.

8. FILTRO DE GALERÍA POR FECHAS EN LA SIGUIENTE SEMANA

Aquí filtraremos la galería para que muestre solo las fechas en la próxima semana. El código que introduciremos en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Today()-(Weekday(Today(), StartOfWeek.Monday))+7,
        EndDate: DateAdd(Today(),(7- Weekday(Today(),StartOfWeek.Sunday))+7,Days)
    },
    Filter(
        'Calendar Dates',
        CalendarDate > StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida, la galería nos mostrará solo las filas con una fecha en la próxima semana, siendo la fecha del día de hoy 08/04/2021.

9. FILTRO DE GALERÍA POR FECHAS EN LAS SIGUIENTES ‘N’ SEMANAS

Con este filtro haremos que la galería nos muestre solo las fechas dentro del siguiente ‘N’ número de semanas en donde ‘N’ es un número especificado por el creador de la app.

Vamos a usar este código en la propiedad Items de la galería:

With(
    {
        StartDate: Today(),
        EndDate: Today() + (7 * 3) // change this number
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate < EndDate
    )
)

Y esto nos dará como salida las filas con una fecha dentro de las siguientes tres semanas, siendo la fecha actual 08/04/2021.

10. FILTRO DE GALERÍA POR FECHAS EN LA SEMANA PASADA

Vamos a filtrar una galería de Power Apps para que muestre solo las fechas en la semana pasada.

Nuestro código a usar en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Today()-(Weekday(Today(), StartOfWeek.Monday))-7,
        EndDate: DateAdd(Today(),(7- Weekday(Today(),StartOfWeek.Sunday))-7,Days)
    },
    Filter(
        'Calendar Dates',
        CalendarDate > StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida, la galería solo nos mostrará las filas con una fecha en la semana pasada, siendo la fecha actual 08/04/2021.

11. FILTRO DE GALERÍA POR FECHAS EN LAS ‘N’ SEMANAS ANTERIORES

Ahora vamos a filtrar una galería para que muestre solo las fechas dentro del anterior ‘N’ número de semanas en donde ‘N’ es un número especificado por el creador de la app.

Introduciremos el siguiente código en la propiedad Items de la galería:

With(
    {
        StartDate: Today() - (7 * 3), // change this number
        EndDate: Today()
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate < EndDate
    )
)

Como resultado de salida se nos mostrarán solo las filas con una fecha dentro de las tres semanas anteriores, siendo la fecha actual 08/04/2021.

Filtrar la galería por meses

12. FILTRO DE GALERÍA POR FECHAS EN EL MES ACTUAL

Entrado en filtros por mes, lo siguiente será filtrar una galería para que solo nos muestre las fechas en el mes actual. Usando la lista de SharePoint de siempre como nuestro punto de entrada, vamos a usar este código en la propiedad Items de la galería:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today()),
            1
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today())+1,
            1
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Y como resultado de salida, la galería nos mostrará solo las filas con una fecha dentro del mes actual, siendo la fecha actual 08/04/2021.

13. FILTRO DE GALERÍA POR FECHAS EN EL SIGUIENTE MES

Ahora vamos a filtrar la galería de Power Apps para que solo nos muestre las fechas en el siguiente mes. El código a introducir en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())+1,
            1
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today())+2,
            1
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Y el resultado nos mostrará solo las filas que tengan una fecha en el siguiente mes, siendo la fecha actual 08/04/2021.

14. FILTRO DE GALERÍA POR FECHAS EN LOS SIGUIENTES ‘N’ MESES

Ahora vamos a filtrar una galería para que solo nos muestre las fechas dentro del siguiente ‘N’ número de meses en donde N es un número especificado por el creador de la app.

Usando la misma lista de SharePoint como nuestra entrada, vamos a usar este código en la propiedad Items de la galería:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today()),
            Day(Today())
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today())+2, //change this number
            Day(Today())
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Y como resultado de salida, la galería nos mostrará solo las filas con una fecha en los siguientes dos meses, según especificamos para este ejemplo, siendo la fecha actual 08/04/2021.

15. FILTRO DE GALERÍA POR FECHAS EN EL MES ANTERIOR

Para este filtro vamos a mostrar solo las fechas en el último mes. En base a la misma lista de SharePoint vamos a introducir el siguiente código en la propiedad Items de la galería:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())-1
            ,1
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today())
            ,1
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida la galería nos mostrará solo las fechas con una fecha en el mes anterior, siendo la fecha actual 08/04/2021.

16. FILTRO DE GALERÍA POR FECHAS EN LOS ‘N’ MESES ANTERIORES

Vamos a filtrar una galería para que solo nos muestre las fechas dentro de los ‘N’ meses previos, en donde N es un número especificado por el creador de la app.

En base a la misma lista de SharePoint usaremos el siguiente código en la propiedad Items de la galería.

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())-1, // change this number
            Day(Today())
        )+1,
        EndDate: Date(
            Year(Today()),
            Month(Today()),
            Day(Today())
        )
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida, la galería solo nos mostrará las filas con una fecha en los dos meses previos, siendo la fecha actual 08/04/2021.

Fechas que componen el trimestre

17. FILTRO DE GALERÍA POR FECHAS EN EL TRIMESTRE ACTUAL

Ahora vamos a filtrar una galería para que nos muestre solo las fechas en el trimestre actual. Usando la misma lista de SharePoint como entrada, introduciremos el siguiente código en la propiedad Items de una galería.

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())
            -If(
                Mod(Month(Today())-1,3) = 0,
                0,
                Mod( Month(Today())-1, 3)
            ),
            1
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today()) + 3-Mod(Month(Today())-1,3),
            1
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

El resultado de salida nos mostrará solo las filas con una fecha en el trimestre actual.

18. FILTRO DE GALERÍA POR FECHAS EN EL SIGUIENTE TRIMESTRE

Aquí filtraremos una galería para que nos muestre solo las fechas en el siguiente trimestre. El código a introducir en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())
            -If(
                Mod(Month(Today())-1,3) = 0,
                0,
                Mod( Month(Today())-1, 3)
            )+3,
            1
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today()) + 3-Mod(Month(Today())-1,3)+3,
            1
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida, la galería nos mostrará solo las filas con una fecha en el siguiente trimestre

19. FILTRO DE GALERÍA POR FECHAS EN LOS SIGUIENTES ‘N’ TRIMESTRES

Vamos a filtrar una galería de Power Apps para que nos muestre solo las fechas dentro del siguiente ‘N’ número de trimestres, en donde N es un número especificado por el creador de la app.

El código a usar en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today()),
With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today()),
            Day(Today())
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today())+(3*2), //change this number
            Day(Today())
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida la galería nos mostrará solo las filas con una fecha en los siguientes dos trimestres, según hemos especificado en el código anterior. La fecha actual es 08/04/2021.

[NOTA 2]

20. FILTRO DE GALERÍA POR FECHAS EN EL ÚLTIMO TRIMESTRE

Vamos a filtrar una galería de Power Apps para que nos muestre solo las fechas en el último trimestre. En base a nuestra lista de SharePoint vamos a introducir el siguiente código en la propiedad Items de la galería:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())
            -If(
                Mod(Month(Today())-1,3) = 0,
                0,
                Mod( Month(Today())-1, 3)
            )-3,
            1
        ),
        EndDate: Date(
            Year(Today()),
            Month(Today()) + 3-Mod(Month(Today())-1,3)-3,
            1
        )-1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida, la galería nos mostrará solo las filas con una fecha en el último trimestre, siendo la fecha actual 08/04/2021.

[NOTA 2]

21. FILTRO DE GALERÍA POR FECHAS EN LOS ‘N’ TRIMESTRES ANTERIORES

Vamos a filtrar una galería para que muestre solo las fechas dentro del anterior ‘N’ número de trimestres en donde N es un número especificado por el creador de la app.

El código a introducir en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today())-(3*2), //change this number
            Day(Today())
        )+1,
        EndDate: Date(
            Year(Today()),
            Month(Today()), 
            Day(Today())
        )
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida, la galería solo nos mostrará las filas con una fecha en los dos trimestres anteriores, según hemos especificado. La fecha actual es 08/04/2021.

Mostrar todo un año completo

22. FILTRO DE GALERÍA POR FECHAS EN EL AÑO ACTUAL

Ahora vamos a filtrar una galería de Power Apps para que solo muestre las fechas en el año actual. El código que vamos a usar en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today()),
            1,
            1
        ),
        EndDate: Date(
            Year(Today()),
            12,
            31
        )
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como salida, la galería nos mostrará solo las filas con una fecha en el año actual, siendo la fecha actual 08/04/2021.

23. FILTRO DE GALERÍA POR FECHAS EN EL SIGUIENTE AÑO

Vamos a filtrar la galería para que muestre solo las fechas en el siguiente año. El código a usar en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today())+1,
            1,
            1
        ),
        EndDate: Date(
            Year(Today())+1,
            12,
            31
        )
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida la galería nos mostrará solo las filas con una fecha en el siguiente año. La fecha actual es 08/04/2021.

24. FILTRO DE GALERÍA POR FECHAS EN LOS SIGUIENTES ‘N’ AÑOS

Vamos a filtrar una galería para que muestre solo las fechas dentro del siguientes ‘N’ número de años en donde N es un número especificado por el creador de la app.

El código a emplear en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today()),
            Month(Today()),
            Day(Today())
        ),
        EndDate: Date(
            Year(Today()) + 2, // change this number
            Month(Today()),
            Day(Today())
        ) - 1
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado la galería nos mostrará solo las filas con una fecha en los siguientes dos años, siendo la fecha actual 08/04/2021.

25. FILTRO DE GALERÍA POR FECHAS EN EL AÑO PASADO

Con este filtro la galería nos mostrará solo las fechas en el año pasado. Usaremos este código en la propiedad Items de la galería:

With(
    {
        StartDate: Date(
            Year(Today())-1,
            1,
            1
        ),
        EndDate: Date(
            Year(Today())-1,
            12,
            31
        )
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

El resultado de salida nos mostrará solo las filas con una fecha en el siguiente año, siendo la fecha actual 08/04/2021.

26. FILTRO DE GALERÍA POR FECHAS EN LOS ‘N’ AÑOS ANTERIORES

Con este filtro de galería solo se nos mostrarán las fechas dentro de los anteriores ‘N’ años en donde N es un número especificado por el creador de la app.

El código a usar en la propiedad Items de la galería es el siguiente:

With(
    {
        StartDate: Date(
            Year(Today())-2, // change this number
            Month(Today()),
            Day(Today())
        )+ 1,
        EndDate: Date(
            Year(Today()),
            Month(Today()),
            Day(Today())
        )
    },
    Filter(
        'Calendar Dates',
        CalendarDate >= StartDate,
        CalendarDate <= EndDate
    )
)

Como resultado de salida la galería nos mostrará solo las filas con una fecha en los dos años anteriores, según hemos especificado, siendo la fecha actual 08/04/2021.