9 ejemplos Cute que podemos hacer con Buscarx.

0

Hola de nuevo, hoy vamos a revisar algunos ejemplos que podemos hacer con la nueva función Buscarx de Excel 365.

Para esto, usaremos una tabla llamada “Ventas” con la que haremos nuestros ejercicios. Puedes descargar el libro aquí.

1. Buscar la última venta neta de Isabel

Solución.

=BUSCARX($C$2,VENTAS[VENDEDOR],VENTAS[VENTA NETA],0,-1)          

A diferencia de todas las funciones de Búsqueda, Buscarx tiene la capacidad de devolver el ultimo valor coincidente de un valor buscado.

ejemplo buscarx ultimo valor

En este caso podemos ver como la ultima venta de Isabel es 25,576, esto funciona ya que agregamos el tipo_busqueda a -1.

2. Buscar cuando fue la venta más grande de todas.

Solución.

=BUSCARX(MAX(VENTAS[VENTA NETA]),VENTAS[VENTA NETA],VENTAS[FECHA],0)          

Combinando la función MAX con Buscarx podemos obtener el valor máximo de la columna venta neta para usarlo como valor de búsqueda en la columna fecha.

buscarx_maximo

Con este mismo método podríamos obtener el nombre del vendedor, las piezas que corresponden o cambiar a la función MIN para obtener los mínimos.

3. Buscar quien hizo la tercera venta mas grande.

Solución.

=BUSCARX(C2,JERARQUIA.EQV(VENTAS[VENTA NETA],VENTAS[VENTA NETA],0),VENTAS[VENDEDOR],0)               

Un truco mas que interesante que aprendí esta semana. Si combinamos la función BuscarX con JERARQUIA.EQV y damos como criterio de búsqueda un numero n, podemos obtener cualquier posición de una lista sin problemas.

buscarx_jerarquia

Cambiando el símbolo de la JERARQUIA.EQV a ascendente (ósea 0 a 1) puedes traer el n número más chico.

4. Quien fue el atrevido que vendió solo $10,267.00

Solución.

=BUSCARX(C2,VENTAS[VENTA NETA],VENTAS[VENDEDOR],0) 

Olvidémonos de Indice+Coincidir y esas formulas raras. Con BuscarX podríamos buscar cualquier valor este en la primera columna o no. En este caso María vendió esa cantidad tan baja, por lo que podremos llamarle la atención de una forma más rápida.

buscarx_indice_coincidir

Adicional a esto, las búsquedas pueden ser de arriba abajo o abajo a arriba como con BuscarH.

5. El muchacho este que empieza con J.

Solución.

=BUSCARX(C2,VENTAS[VENDEDOR],VENTAS[VENDEDOR],2) 

¡Obvio es Juan señor! Pero si no nos acordamos, podemos realizar una búsqueda de comodines incluyendo el símbolo * a nuestro valor buscado.

buscarx_comodines

6. Quien realizo la última venta en la tabla.

Solución.

=BUSCARX(C2,VENTAS[VENDEDOR],VENTAS[VENDEDOR],2,-1)  

Una solución divertida para encontrar el ultimo registro de nuestros datos es solo usar el comodin * sin nada mas y cambiar el modo_busqueda a -1 (de abajo a arriba). Con esto conseguiremos que Excel traiga el ultimo valor sin importar que sea.

buscarx_comodines

7. Vendió algo Isabel el día 10/09/2019.

Solución.

=BUSCARX(C2,FILTRAR(VENTAS[FECHA],VENTAS[VENDEDOR]="ISABEL"),FILTRAR(VENTAS[VENTA NETA],VENTAS[VENDEDOR]="ISABEL"),0)

Con los nuevos conjuntos de funciones que Excel agrego se pueden hacer cosas muy interesantes. Si combinamos BuscarX con FILTRAR encontraremos que podemos hacer pequeñas matrices separadas de búsqueda. Con esta función se generan dos mini matrices coincidentes y filtradas por el nombre de Isabel, con lo que todos los demás valores quedan descartados automáticamente.

buscarx_filtrar

8. No se donde este la columna Piezas, pero quiero ver las de Pedro.

Solución.

=BUSCARX("PEDRO",VENTAS[VENDEDOR],BUSCARX($C$2,VENTAS[#Encabezados],VENTAS),0)     

Y obviamente no podía faltar el clásico Buscarx dentro de otro BuscarX. Al anidar las funciones, logramos localizar una columna sin saber exactamente donde esta, logrando hacer totalmente dinámica nuestra función.

ejemplo buscarx anidado

Esto es lo mismo que encontrar el número de columna en BUSCARV o INDICE, pero en lugar de crear un numero creamos una matriz de valores.

9. Y cuanto vendió Angel de Odin a todo esto…

Solución.

=BUSCARX("JUAN",VENTAS[VENDEDOR],BUSCARX($C$2,VENTAS[#Encabezados],VENTAS),0)

Nada, el solo escribe jajaja… Y el resultado será el de siempre, un espantoso #N/D.

ejemplo buscarx na

Todo esto es solo una muestra de las cosas Cutes que podemos hacer con BuscarX, por lo que te invito a que sigas jugando con la nueva maestra de las funciones de búsqueda.

Cualquier duda nos leemos abajo.

9 ejemplos Cute que podemos hacer con Buscarx.
0

Deja una respuesta

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *

Scroll hacia arriba